Кажется, нет простого способа получить длину строки в пакетном файле. Например,
SET MY_STRING=abcdefg
SET /A MY_STRING_LEN=???
Как я нашел бы длину строки MY_STRING
?
Бонусные очки, если указатели на функцию длины строки все возможные символы в строках включая символы ESC, как это: !%^^()^!
.
Как существует не создан в функции для длины строки, можно записать собственную функцию как этот:
@echo off
setlocal
REM *** Some tests, to check the functionality ***
REM *** An emptyStr has the length 0
set "emptyString="
call :strlen result emptyString
echo %result%
REM *** This string has the length 14
set "myString=abcdef!%%^^()^!"
call :strlen result myString
echo %result%
REM *** This string has the maximum length of 8191
setlocal EnableDelayedExpansion
set "long=."
FOR /L %%n in (1 1 13) DO set "long=!long:~-4000!!long:~-4000!"
(set^ longString=!long!!long:~-191!)
call :strlen result longString
echo %result%
goto :eof
REM ********* function *****************************
:strlen <resultVar> <stringVar>
(
setlocal EnableDelayedExpansion
(set^ tmp=!%~2!)
if defined tmp (
set "len=1"
for %%P in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
if "!tmp:~%%P,1!" NEQ "" (
set /a "len+=%%P"
set "tmp=!tmp:~%%P!"
)
)
) ELSE (
set len=0
)
)
(
endlocal
set "%~1=%len%"
exit /b
)
для Этой функции всегда нужны 13 циклов вместо простой функции strlen, для которой нужны strlen-циклы.
Это обрабатывает все символы.
странное выражение (set^ tmp=!%~2!)
необходимо для обработки крайних длинных строк, еще не возможно скопировать их.
@ECHO OFF
SET string=
SET /A stringLength=0
:CheckNextLetter
REM Subtract the first letter and count up until the string="".
IF "%string%" NEQ "" (
SET string=%string:~1%
SET /A stringLength=%stringLength%+1
GOTO :CheckNextLetter
) ELSE (
GOTO :TheEnd
)
:TheEnd
ECHO There is %stringLength% character^(s^) in the string.
PAUSE
Это работает на меня. Надежда это полезно для кого-то еще. Никакая потребность корректироваться для любой длины. Я просто удаляю первую букву и выдерживаю сравнение с, "" пока строка не равняется "".
Это Много Simplier!
Чистое пакетное решение. Никакие временные файлы. Никакие длинные сценарии.
@echo off
setlocal enabledelayedexpansion
set String=abcde12345
for /L %%x in (1,1,1000) do ( if "!String:~%%x!"=="" set Lenght=%%x & goto Result )
:Result
echo Lenght: !Lenght!
1000
максимальная предполагаемая строковая длина. Измените его на основе своих потребностей.
Я хочу снабдить это предисловием путем высказывания, что я не знаю много о написании кода. но думал, что я совместно использую решение, которое я, кажется, предложил. Большинство ответов здесь отчасти пробежалось через мою голову, таким образом, мне было любопытно знать, сопоставимо ли то, что я записал.
@echo off
set stringLength=0
call:stringEater "It counts most characters"
echo %stringLength%
echo.&pause&goto:eof
:stringEater
set var=%~1
:subString
set n=%var:~0,1%
if "%n%"=="" (
goto:eof
) else if "%n%"==" " (
set /a stringLength=%stringLength%+1
) else (
set /a stringLength=%stringLength%+1
)
set var=%var:~1,1000%
if "%var%"=="" (
goto:eof
) else (
goto subString
)
goto:eof
@echo off
:: warning doesn't like * ( in mystring
setlocal enabledelayedexpansion
set mystring=this is my string to be counted forty one
call :getsize %mystring%
echo count=%count% of "%mystring%"
set mystring=this is my string to be counted
call :getsize %mystring%
echo count=%count% of "%mystring%"
set mystring=this is my string
call :getsize %mystring%
echo count=%count% of "%mystring%"
echo.
pause
goto :eof
:: Get length of mystring line ######### subroutine getsize ########
:getsize
set count=0
for /l %%n in (0,1,2000) do (
set chars=
set chars=!mystring:~%%n!
if defined chars set /a count+=1
)
goto :eof
:: ############## end of subroutine getsize ########################
@echo off & setlocal EnableDelayedExpansion
set Var=finding the length of strings
for /l %%A in (0,1,10000) do if not "%Var%"=="!Var:~0,%%A!" (set /a Length+=1) else (echo !Length! & pause & exit /b)
устанавливает var на то, что Вы хотите найти длиной его или изменить его для установки/p var = так, чтобы вводы данных пользователем он. Помещение этого здесь для дальнейшего использования.
Мне нравится два подхода строки из jmh_gr.
Это не будет работать с единственными числами цифры, если Вы не поместите ()
вокруг части команды перед перенаправлением. с тех пор 1>
специальная команда "Echo is On", будет перенаправлен в файл.
Этот пример должен заботиться о единственных числах цифры, но не других специальных символах такой как <
, который может быть в строке.
(ECHO %strvar%)> tempfile.txt
Просто другой сценарий пакетной обработки для вычисления длины строки, во всего нескольких строках. Это не может быть самым быстрым, но это является довольно маленьким. Подпрограмма ": len" возвращает длину во втором параметре. Первый параметр является фактической проанализированной строкой. Отметьте - специальных символов нужно оставить, который имеет место с любой строкой в пакетном файле.
@echo off
setlocal
call :len "Sample text" a
echo The string has %a% characters.
endlocal
goto :eof
:len <string> <length_variable> - note: string must be quoted because it may have spaces
setlocal enabledelayedexpansion&set l=0&set str=%~1
:len_loop
set x=!str:~%l%,1!&if not defined x (endlocal&set "%~2=%l%"&goto :eof)
set /a l=%l%+1&goto :len_loop
Просто найденный Окончательным решением:
set "MYSTRING=abcdef!%%^^()^!"
(echo "%MYSTRING%" & echo.) | findstr /O . | more +1 | (set /P RESULT= & call exit /B %%RESULT%%)
set /A STRLENGTH=%ERRORLEVEL%-5
echo string "%MYSTRING%" length = %STRLENGTH%
вывод:
string "abcdef!%^^()^!" length = 14
Это обрабатывает символы ESC, порядок величины, более простой затем большинство решений выше, и не содержит циклов, магических чисел, DelayedExpansion, временных файлов, и т.д.
В случае, если использование вне сценария пакетной обработки (означают помещать команды в консоль вручную), замените %%RESULT%%
ключ %RESULT%
.
В случае необходимости, %ERRORLEVEL%
переменная могла быть установлена на FALSE
использование любой команды NOP, например, echo. >nul
Первые несколько строк должны просто продемонстрировать: функция strLen.
@echo off
set "strToMeasure=This is a string"
call :strLen strToMeasure strlen
echo.String is %strlen% characters long
exit /b
:strLen
setlocal enabledelayedexpansion
:strLen_Loop
if not "!%1:~%len%!"=="" set /A len+=1 & goto :strLen_Loop
(endlocal & set %2=%len%)
goto :eof
, Конечно, это не совсем как эффективное в "13 циклах" версия, обеспеченная jeb. Но легче понять, и Ваш компьютер на 3 ГГц может проскользнуть через несколько тысяч повторений в небольшой части секунды.
Я предпочитаю принятый ответ jeb - это - самое быстрое известное решение и то, которое я использую в своих собственных сценариях. (На самом деле существует несколько дополнительной оптимизации, обсудил на DosTips, но я не думаю, что они стоят того)
, Но это интересно придумать новые эффективные алгоритмы. Вот новый алгоритм, который использует FINDSTR/O опция:
@echo off
setlocal
set "test=Hello world!"
:: Echo the length of TEST
call :strLen test
:: Store the length of TEST in LEN
call :strLen test len
echo len=%len%
exit /b
:strLen strVar [rtnVar]
setlocal disableDelayedExpansion
set len=0
if defined %~1 for /f "delims=:" %%N in (
'"(cmd /v:on /c echo(!%~1!&echo()|findstr /o ^^"'
) do set /a "len=%%N-3"
endlocal & if "%~2" neq "" (set %~2=%len%) else echo %len%
exit /b
код вычитает 3, потому что синтаксический анализатор манипулирует командой и добавляет пространство, прежде чем CMD/V/C выполнит его. Это может быть предотвращено при помощи (echo(!%~1!^^^)
.
Для тех, которые хотят абсолютную самую быструю возможную производительность, , ответ jeb может быть принят для использования в качестве пакет "макрос" с аргументами . Это - усовершенствованная пакетная техника devloped законченный в DosTips, который устраняет по сути медленный процесс ВЫЗОВА a: подпрограмма. Можно добраться [еще 117] фон на понятиях позади пакетных макросов здесь , но та ссылка использует более примитивный, менее желательный синтаксис.
Ниже оптимизированный @strLen макрос, с примерами, показывающими различия между макросом и: использование подпрограммы, а также разница в производительности.
@echo off
setlocal disableDelayedExpansion
:: -------- Begin macro definitions ----------
set ^"LF=^
%= This creates a variable containing a single linefeed (0x0A) character =%
^"
:: Define %\n% to effectively issue a newline with line continuation
set ^"\n=^^^%LF%%LF%^%LF%%LF%^^"
:: @strLen StrVar [RtnVar]
::
:: Computes the length of string in variable StrVar
:: and stores the result in variable RtnVar.
:: If RtnVar is is not specified, then prints the length to stdout.
::
set @strLen=for %%. in (1 2) do if %%.==2 (%\n%
for /f "tokens=1,2 delims=, " %%1 in ("!argv!") do ( endlocal%\n%
set "s=A!%%~1!"%\n%
set "len=0"%\n%
for %%P in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (%\n%
if "!s:~%%P,1!" neq "" (%\n%
set /a "len+=%%P"%\n%
set "s=!s:~%%P!"%\n%
)%\n%
)%\n%
for %%V in (!len!) do endlocal^&if "%%~2" neq "" (set "%%~2=%%V") else echo %%V%\n%
)%\n%
) else setlocal enableDelayedExpansion^&setlocal^&set argv=,
:: -------- End macro definitions ----------
:: Print out definition of macro
set @strLen
:: Demonstrate usage
set "testString=this has a length of 23"
echo(
echo Testing %%@strLen%% testString
%@strLen% testString
echo(
echo Testing call :strLen testString
call :strLen testString
echo(
echo Testing %%@strLen%% testString rtn
set "rtn="
%@strLen% testString rtn
echo rtn=%rtn%
echo(
echo Testing call :strLen testString rtn
set "rtn="
call :strLen testString rtn
echo rtn=%rtn%
echo(
echo Measuring %%@strLen%% time:
set "t0=%time%"
for /l %%N in (1 1 1000) do %@strlen% testString testLength
set "t1=%time%"
call :printTime
echo(
echo Measuring CALL :strLen time:
set "t0=%time%"
for /l %%N in (1 1 1000) do call :strLen testString testLength
set "t1=%time%"
call :printTime
exit /b
:strlen StrVar [RtnVar]
::
:: Computes the length of string in variable StrVar
:: and stores the result in variable RtnVar.
:: If RtnVar is is not specified, then prints the length to stdout.
::
(
setlocal EnableDelayedExpansion
set "s=A!%~1!"
set "len=0"
for %%P in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
if "!s:~%%P,1!" neq "" (
set /a "len+=%%P"
set "s=!s:~%%P!"
)
)
)
(
endlocal
if "%~2" equ "" (echo %len%) else set "%~2=%len%"
exit /b
)
:printTime
setlocal
for /f "tokens=1-4 delims=:.," %%a in ("%t0: =0%") do set /a "t0=(((1%%a*60)+1%%b)*60+1%%c)*100+1%%d-36610100
for /f "tokens=1-4 delims=:.," %%a in ("%t1: =0%") do set /a "t1=(((1%%a*60)+1%%b)*60+1%%c)*100+1%%d-36610100
set /a tm=t1-t0
if %tm% lss 0 set /a tm+=24*60*60*100
echo %tm:~0,-2%.%tm:~-2% msec
exit /b
- Демонстрационный Вывод -
@strLen=for %. in (1 2) do if %.==2 (
for /f "tokens=1,2 delims=, " %1 in ("!argv!") do ( endlocal
set "s=A!%~1!"
set "len=0"
for %P in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
if "!s:~%P,1!" neq "" (
set /a "len+=%P"
set "s=!s:~%P!"
)
)
for %V in (!len!) do endlocal&if "%~2" neq "" (set "%~2=%V") else echo %V
)
) else setlocal enableDelayedExpansion&setlocal&set argv=,
Testing %@strLen% testString
23
Testing call :strLen testString
23
Testing %@strLen% testString rtn
rtn=23
Testing call :strLen testString rtn
rtn=23
Measuring %@strLen% time:
1.93 msec
Measuring CALL :strLen time:
7.08 msec
Если Вы находитесь на Windows Vista +, то попробуйте этот метод Powershell:
For /F %%L in ('Powershell $Env:MY_STRING.Length') do (
Set MY_STRING_LEN=%%L
)
или альтернативно:
Powershell $Env:MY_STRING.Length > %Temp%\TmpFile.txt
Set /p MY_STRING_LEN = < %Temp%\TmpFile.txt
Del %Temp%\TmpFile.txt
я нахожусь в Windows 7 x64, и это работает на меня.
Можно сделать это в двух строках, полностью в пакетном файле, путем записи строки в файл и затем получения длины файла. Просто необходимо вычесть два байта для составления автоматической CR+LF, добавленной в конец.
Скажем, Ваша строка находится в переменной, названной strvar
:
ECHO %strvar%> tempfile.txt
FOR %%? IN (tempfile.txt) DO ( SET /A strlength=%%~z? - 2 )
длина строки находится теперь в переменной, названной strlength
.
В немного большем количестве деталей:
FOR %%? IN (filename) DO ( ...
: получает информацию о файле SET /A [variable]=[expression]
: оцените выражение численно %%~z?
: Специальное выражение, чтобы заставить длину файла делать пюре из целой команды в одной строке:
ECHO %strvar%>x&FOR %%? IN (x) DO SET /A strlength=%%~z? - 2&del x
Да, конечно, существует простой способ, с помощью vbscript (или powershell).
WScript.Echo Len( WScript.Arguments(0) )
сохраняют это как strlen.vbs
и на Использовании командной строки
c:\test> cscript //nologo strlen.vbs "abcd"
, чтобы цикл получил результат (или используйте vbscript полностью для Вашей задачи сценариев)
, Конечно, удары, имеющие необходимость создать громоздкие обходные решения с помощью пакета и нет никакого оправдания не использовать его, так как vbscript доступен с каждым распределением Windows (и powershell в позже).