изменить определенные столбцы на основе другого столбца с помощью awk и gsub
У меня есть файл (file1) с миллионами строк и столбцов. Примеры данных:
"col1","col2","col3","col4","col5","col6"
"AAA",0,5,10,"BGB",50
"BBB",4,7,10,"BFD",76
"AAA",15,0,0,"BGB",20
"AAA",10,13,10,"DDD",23
Я хочу найти все строки с AAA в col1, а затем получить все строки с BGB в col5. И, наконец, уменьшите на 50% каждое значение в столбцах col2, col3, col4 и col6 (игнорируйте, если значения ячеек равны 0 или пустые). И распечатайте все строки файла. Итак, мой вывод будет выглядеть следующим образом:
"col1","col2","col3","col4","col5","col6"
"AAA",0,2.5,5,"BGB",25
"BBB",4,7,10,"BFD",76
"AAA",7.5,0,0,"BGB",10
"AAA",10,13,10,"DDD",23
Я пробовал следующее, но не смог заставить его работать (также не мог понять, как использовать несколько столбцов в gsub)
grep AAA file1 | awk -F "," '$5~/BGB/ {gsub($6,\substr($6,1,length($6)-1)*0.50\, $6}1'
0
задан glenn jackman
29 July 2021 в 21:51
поделиться
1 ответ
awk может сопоставлять шаблоны, как grep, поэтому вам почти никогда не понадобится grep и awk в конвейере.
Вы можете сделать
awk '
BEGIN {FS = OFS = ","}
$1 ~ /AAA/ && $5 ~ /BGB/ {
if ($2) $2 = $2 / 2
if ($3) $3 = $3 / 2
if ($4) $4 = $4 / 2
if ($6) $6 = $6 / 2
}
1
' file
Или, если хотите сделать столбцы более динамичными
awk -v "columns=2,3,4,6" '
BEGIN {
FS = OFS = ","
n = split(columns, a, /,/)
for (i=1; i<=n; i++) cols[a[i]]=1
}
$1 ~ /AAA/ && $5 ~ /BGB/ {
for (c in cols) if ($c) $c = $c / 2
}
1
' file
1
ответ дан
20 August 2021 в 10:31
поделиться