Измените 2 или больше документа LibreOffice, чтобы иметь то же самое моделирование/форматирование

Используйте инструменты Libreoffice вместо CLI

Когда все, что Вы имеете, является инструментами командной строки, все похоже на проблему командной строки. Я решил записать этому использованию ответа макросы LibreOffice:

1. Используйте цикл командной строки для обработки каждого документа Устройства записи в "бездисплейной" среде.
2. Выполненный макрос для изменения .rtf (Формат RTF) файл документа Устройства записи.
3. Макрос сохранил файл и выход
4. Цикл назад к 1.

Создайте данные тестирования

Создайте два или больше файла, содержащие:

Создайте сценарий ~/Downloads/copy-rtf.sh содержа:

cp ~/Documents/*.rtf ~/Downloads

Mark как исполняемое использование

chmod a+x ~/Downloads/copy-rtf.sh

• Во время разработки и тестирования, изменения макросов *.rtf файлы будут работать против ~/Downloads каталог.
• Перед каждым тестовым типом cd ~/Downloads и выполненный ./copy-rtf.sh
• После того, как вывод прекрасен, они копируются назад в живой каталог.

Каталог Downloads используется потому что:

• у всех есть a ~/Downloads
• это добавляется к регулярно и вручную периодически пустело
• это является более постоянным, чем /tmp/ каталог, который не может сохраниться через перезагрузки.

Выполненный макрос в бездисплейной среде

Используя этот Стек ответ Exchange вызывают Libreoffice Writer из командной строки и передают его глобальное макро-имя для выполнения:

soffice -headless -invisible "vnd.sun.star.script:Standard.Module1.MySubroutine? language=Basic&location=application"

Вышеупомянутый ответ не может работать так, другой метод можно попробовать:

soffice "macro:///Standard.SaveCSV.Main" $1

Установите среду выполнения Java

Для выполнения макросов, Вам нужна установленная среда выполнения Java (JRE). Веб-страница разработчика имеет инструкции для загрузки и установки вручную.

Однако этот AU Вопросы и ответы: https://askubuntu.com/a/728153/307523 предполагает, что это столь же просто как:

sudo apt-add-repository ppa:webupd8team/java
sudo apt-get update
sudo apt-get install oracle-java8-installer oracle-java8-set-default

Я попробовал метод Вопросов и ответов AU и после первого шага добавления PPA, экран-заставка появляется с дополнительной информацией. Самой полезной является ссылка на установку JRE 8 в системах Debian.

Третий шаг установки JRE 8 требует, чтобы Вы использовали Вкладку и Вошли для принятия Лицензионного соглашения. Ваша машина приостановится в течение нескольких минут во время самой тяжелой части процедуры установки.

Теперь откройте LibreOffice и выберите Инструменты-> Опции-> LibreOffice-> Усовершенствованный и установите этот экран:

Нажмите опции для:

• Используйте среду выполнения Java
• Oracle Corporation 1.8.0_161
• Включите макрос, записывающий (экспериментальный)
• Нажать "OK"
• Вас попросят перезапустить, нажать "Restart Now".

Макрос устройства записи LibreOffice

Макрос прочитает весь документ и:

• измените имя шрифта на Ubuntu.
• При заголовке 1 размера шрифта набора к 28
• еще, если размер шрифта является 18 наборами к 22
• еще установите размер шрифта на 12

Макрос сохранит документ и выйдет из Устройства записи Libreoffice.

Выключите диалоговое окно

Сделайте файл сохраняет, и это диалоговое окно подходит:

Выключите это сообщение как шоу на экране. Макрос не может работать правильно, если эта опция идет.

Макро-содержание

Я провел несколько дней, пытаясь записать использование макроса "Инструменты"->, "Макросы"-> "Записывают Макрос"-> "Основной". Сначала это казалось обещанием, но зарегистрированный макрос имел непоследовательное поведение и должен был отказаться для рукописного основного макроса. Найденная справка в Переполнении стека для эксперта там для помощи мне с основным программированием в абсолютных адресах. Вот результат:

Sub ChangeAllFonts
    rem - Change all font names to Ubuntu.
    rem - If heading 1 set font size to 28
    rem - else if font size is 18 set to 22
    rem - else set font size to 12
    rem - The macro will save document and exit LibreOffice Writer.
    Dim oDoc As Object
    Dim oParEnum As Object, oPar As Object, oSecEnum As Object, oSec As Object
    Dim oFamilies As Object, oParaStyles As Object, oStyle As Object
    oDoc = ThisComponent
    oParEnum = oDoc.Text.createEnumeration()
    Do While oParEnum.hasMoreElements()
      oPar = oParEnum.nextElement()
      If oPar.supportsService("com.sun.star.text.Paragraph") Then
        oSecEnum = oPar.createEnumeration()
        Do While oSecEnum.hasMoreElements()
          oSec = oSecEnum.nextElement()
          If oSec.TextPortionType = "Text" Then
            If oSec.ParaStyleName = "Heading 1" Then
                rem ignore for now
            ElseIf oSec.CharHeight = 18 Then
                oSec.CharHeight = 22.0
            Else
                oSec.CharHeight = 12.0
            End If
          End If
        Loop
      End If
    Loop
    oFamilies = oDoc.getStyleFamilies()
    oParaStyles = oFamilies.getByName("ParagraphStyles")
    oStyle = oParaStyles.getByName("Heading 1")
    oStyle.setPropertyValue("CharHeight", 28.0)
    FileSave
    StarDesktop.terminate()
End Sub

rem Above subroutine is missing call to UbuntuFontName ()
rem also it is calling oStyle.setPropertyValue("CharHeight", 28.0)
rem which may cause problems. Will test. Also StarDesktop.terminate ()
rem is known to cause problems and will likely be reworked with a
rem a dialog box telling operator the program is finished and maybe
rem to press <Alt>+<F4>.

rem ========= Original code below for possible recycling ===========

Sub AllFonts
rem - change all font names to Ubuntu.
rem - If heading 1 set font size to 28
rem - else if font size is 18 set to 22
rem - else set font size to 12

rem The macro will save document and exit Libreoffice Writer.

Dim CharHeight As Long, oSel as Object, oTC as Object
Dim CharStyleName As String
Dim oParEnum as Object, oPar as Object, oSecEnum as Object, oSec as Object
Dim oVC as Object, oText As Object
Dim oParSection        'Current Section

oText = ThisComponent.Text
oSel = ThisComponent.CurrentSelection.getByIndex(0) 'get the current selection
oTC = oText.createTextCursorByRange(oSel)           ' and span it with a cursor

rem Scan the cursor range for chunks of given text size.
rem (Doesn't work - affects the whole document)

oParEnum = oTC.Text.createEnumeration()
Do While oParEnum.hasMoreElements()
  oPar = oParEnum.nextElement()
  If oPar.supportsService("com.sun.star.text.Paragraph") Then
    oSecEnum = oPar.createEnumeration()
    oParSection = oSecEnum.nextElement()
    Do While oSecEnum.hasMoreElements()
      oSec = oSecEnum.nextElement()
      If oSec.TextPortionType = "Text" Then
        CharStyleName = oParSection.CharStyleName
        CharHeight = oSec.CharHeight
        if CharStyleName = "Heading 1" Then
            oSec.CharHeight = 28
        elseif CharHeight = 18 Then
            oSec.CharHeight = 22
        else
            oSec.CharHeight = 12
        End If
      End If
    Loop
  End If

Loop

FileSave
stardesktop.terminate()

End Sub


Sub UbuntuFontName
rem ----------------------------------------------------------------------
rem define variables
dim document   as object
dim dispatcher as object
rem ----------------------------------------------------------------------
rem get access to the document
document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")

rem ----------- Select all text ------------------------------------------
dispatcher.executeDispatch(document, ".uno:SelectAll", "", 0, Array())

rem ----------- Change all fonts to Ubuntu -------------------------------
dim args5(4) as new com.sun.star.beans.PropertyValue
args5(0).Name = "CharFontName.StyleName"
args5(0).Value = ""
args5(1).Name = "CharFontName.Pitch"
args5(1).Value = 2
args5(2).Name = "CharFontName.CharSet"
args5(2).Value = -1
args5(3).Name = "CharFontName.Family"
args5(3).Value = 0
args5(4).Name = "CharFontName.FamilyName"
args5(4).Value = "Ubuntu"

dispatcher.executeDispatch(document, ".uno:CharFontName", "", 0, args5())

end sub


sub FileSave
rem ----------------------------------------------------------------------
rem define variables
dim document   as object
dim dispatcher as object
rem ----------------------------------------------------------------------
rem get access to the document
document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")

rem ----------------------------------------------------------------------
dispatcher.executeDispatch(document, ".uno:Save", "", 0, Array())

end sub