Если ваш скайп подключен к сети, то есть вы вошли в систему и проблем с сетью нет, вы можете сделать следующее:

1. В списке телефонных номеров скайпа есть кнопка В нижней части окна Skype, который дает вам доступ к настройкам. Нажмите на это, и появится меню «Параметры».
2. Зайдите в уведомления и выберите «Звонок входящего вызова». Теперь выберите «Расширенный просмотр».
3. В нижней части «расширенного представления» находится опция «Выполнить следующий скрипт», в которой вы вводите полный путь к файлу вашего скрипта.
4. Нажмите «Применить».

Сценарий

global _proc
global use_growl

tell application "System Events" to set _proc to name of processes as list
if _proc contains "GrowlHelperApp" then
    set use_growl to true
    my growlRegister()
else
    set use_growl to false
end if

if _proc contains "Skype" then
    tell application "Skype"
        set calls to send command "SEARCH ACTIVECALLS" script name "AnsweringScript"
        set callID to last word of calls
        if callID is not "CALLS" then
            set status to send command "GET CALL " & callID & " STATUS" script name "AnsweringScript"
            if last word of status is "RINGING" then
                send command "ALTER CALL " & callID & " ANSWER" script name "AnsweringScript"
                my growlNotify("SkypeAnswer", "Answering call")
                return
            else
                send command "ALTER CALL " & callID & " HANGUP" script name "AnsweringScript"
                my growlNotify("SkypeAnswer", "Hanging up")
            end if
        else
            my growlNotify("SkypeAnswer", "No call found to answer or hang up")
        end if
    end tell
else
    my growlNotify("SkypeAnswer", "Skype not detected")
end if

using terms from application "GrowlHelperApp"
    on growlRegister()
        tell application "GrowlHelperApp"
            register as application "SkypeAnswer" all notifications {"Alert"} default notifications {"Alert"} icon of application "Skype.app"
        end tell
    end growlRegister

    on growlNotify(grrTitle, grrDescription)
        if use_growl is true then
            tell application "GrowlHelperApp"
                notify with name "Alert" title grrTitle description grrDescription application name "SkypeAnswer"
            end tell
        end if
    end growlNotify
end using terms from

Ссылка: 1

С уважением

BHM